/*
 *  SPL - The SPL Programming Language
 *  Copyright (C) 2006  Clifford Wolf <clifford@clifford.at>
 *
 *  This program is free software; you can redistribute it and/or modify
 *  it under the terms of the GNU General Public License as published by
 *  the Free Software Foundation; either version 2 of the License, or
 *  (at your option) any later version.
 *
 *  This program is distributed in the hope that it will be useful,
 *  but WITHOUT ANY WARRANTY; without even the implied warranty of
 *  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 *  GNU General Public License for more details.
 *
 *  You should have received a copy of the GNU General Public License
 *  along with this program; if not, write to the Free Software
 *  Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
 *
 *  example66.spl: example for <spl:else>, <splif:*> and <splcall:*> tags
 */

// SKIP_IF_NO_REGEX

function splif_greater(%args)
{
	return args.a > args.b;
}

function splcall_substitue(textfunc, %args)
{
	return textfunc() =~ s/$args.from/$args.to/Rg;
}

function splcall_myloop(textfunc, %args)
{
	var mytextfunc, myctx, text;

	mytextfunc := textfunc;
	myctx.[*] = mytextfunc.[*];
	mytextfunc.[*] = myctx;

	for (var i = args.from; i<=args.to; i++) {
		myctx["counter"] = i;
		text ~= mytextfunc();
	}

	return text;
}

function splcall_add(%args)
{
	return args.a + args.b;
}

write(<:>
	<spl:if code="0">
	: Barfoo
	</spl:if>
	<spl:else>
	: Foobar
	</spl:else>
	<splif:greater a="42" b=(4*2)>
	: 42 is greater then 4*2.
	</splif:greater>
	<spl:else>
	: 42 is not greater than 4*2.
	</spl:else>
	<splif:greater a=(4+2) b='42'>
	: 4+2 is greater then 42.
	</splif:greater>
	<spl:else>
	: 4+2 is not greater than 42.
	</spl:else>
	<splcall:substitue from="te.t" to='de${'m'}o'>
	: This is a test!
	</splcall:substitue>
	: The answer is <splcall:add a=(24) b=(18) />.
	<spl:foreach var="[]i" list="['A', 'B']">
	  <splcall:myloop from="7" to="9">
	: $i: Current counter: $counter
	  </splcall:myloop>
	</spl:foreach>
</>);