/*
 *  SPL - The SPL Programming Language
 *  Copyright (C) 2004, 2005  Clifford Wolf <clifford@clifford.at>
 *
 *  This program is free software; you can redistribute it and/or modify
 *  it under the terms of the GNU General Public License as published by
 *  the Free Software Foundation; either version 2 of the License, or
 *  (at your option) any later version.
 *
 *  This program is distributed in the hope that it will be useful,
 *  but WITHOUT ANY WARRANTY; without even the implied warranty of
 *  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 *  GNU General Public License for more details.
 *
 *  You should have received a copy of the GNU General Public License
 *  along with this program; if not, write to the Free Software
 *  Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
 *
 *  mod_sql_utils.c: Various SQL utility functions
 */

/**
 * Additional SQL helper functions.
 *
 * The [[sql:]] module just provides a generic function for doing SQL queries,
 * namely [[sql:sql()]]. This module declares some wrapper functions for
 * [[sql:sql()]] which do implement common usage scenarios for [[sql:sql()]].
 */

load "sql";

/**
 * Execute the query and return the first field of the first tuple in the
 * result.
 */
function sql_value(db, query)
{
	var r = sql(db, query);
	return shift r.[0];
}

/**
 * Execute the query and return the first tuple in the result.
 */
function sql_tuple(db, query)
{
	var r = sql(db, query);
	return r.[0];
}

/**
 * Execute the query, which must return fields named 'key' and 'value', and
 * return a hash created from this result set.
 */
function sql_keyval(db, query)
{
	var r = sql(db, query);
	var ret;

	foreach i (r)
		ret.[r.[i].key] = r.[i].value;
	
	return ret;
}

/**
 * Execute the query, which must return fields named 'value', and return an
 * array created from this result set.
 */
function sql_array(db, query)
{
	var r = sql(db, query);
	var ret;

	foreach i (r)
		push ret, r.[i].value;
	
	return ret;
}